Home

Error and Exception Handling

 

Introduction to Errors

 

Overview

Apparently no matter how careful and meticulous you are, there will be problems with your code or your application. Some problems will come from you. Some problems will be caused by users. And some problems will be caused by neither you nor your users. This means that there are things you can fix. There are things you can avoid as much as possible. And there are things beyond your control. Still, as much as you can, try anticipating any type of problem you imagine may occur when a user is using your application, and take action as much as possible to avoid bad situations.

 

Error Categories

As mentioned above, there are three main types of problems that you will deal with, directly or indirectly:

  1. Syntax: A syntax error comes from your mistyping a word or forming a bad expression in your code. It could be that you misspelled a keyword such as ByVel instead of ByVal. It could also be a bad expression such as 524+ + 62.55. It could be a "grammar" error such as providing the name of a variable before its data type when declaring a variable (quite common for those who regularly transition from different languages (C/C++, Pascal, C#, Java))

    When you use Microsoft Visual Studio to write your code, it would point out the errors while you are writing your code, giving up ample time to fix them. When you compile your application, the compiler can let you know about other syntax errors. For this reason, syntax errors are almost the easiest to fix. Most of the time, the compiler would point out where the problem is so you can fix it
  2. Run-Time: After all syntax errors have been fixed, the program may be ready for the user. There are different types of problems that a user may face when interacting with your program. For example, imagine that, in your code, you indicate that a picture would be loaded and displayed to the user but you forget to ship the picture or the directory of the picture indicated in your code becomes different when a user opens your application. In this case, when you compiled and executed the application in your machine, everything was fine; but when you distribute the application and your user tries to use it, it does not work. This is a type of run-time error
  3. Logic: These are errors that do not fit in any of the above categories. They could be caused by the user misusing your application, a problem with the computer on which the application is running while the same application is working fine in another computer. Because logic errors can be vague, they can also be difficult (even, to the extreme, impossible) to fix

One of the best qualities of an effective programmer is to anticipate as many problems as possible and to deal with them in the early stages. Some problems can be easy to fix. With some others, you will simply need to build more experience to know how to fix them. Unfortunately, it will not be unusual to have users asking you to fix your application when a problem may not come from it.

Classic Error Handling

 

Introduction

From its early stages, Microsoft Visual Basic has always made it a priority to deal with errors. Most or early errors occur in your code. The Visual Studio IDE can help you detect syntax errors and fix them. In fact, a feature almost unique to the Visual Basic IDE, which is not available in Visual C++ and some versions of Visual C#, is that its Code Editor detects problems immediately as soon as they appear in your code. In fact, in previous versions of Visual Basic and in VBA (Microsoft Access), a message box would display, prompting you to fix the problem. This has always made Visual Basic one of the friendliest programming environments around. When you think everything is fine, compile your code. If there is a syntax error that that the IDE did not signal or that you ignored when writing your code, the compiler will let you know. If there is no syntax error, the compilation will be over and the executable will be ready. You can then execute the application to see the result. If the user is not asked to provide value(s), you are less likely to get a run-time error.

A run-time error is one that occurs when using your application. Consider the following application:

Exception Handling
Imports System.Drawing
Imports System.Windows.Forms

Module Exercise

    Public Class Starter
        Inherits Form

        Private lblNumber As Label
        Private txtNumber As TextBox
        Friend WithEvents btnCalculate As Button
        Private lblResult As Label
        Private txtResult As TextBox

        Dim components As System.ComponentModel.Container

        Public Sub New()
            InitializeComponent()
        End Sub

        Public Sub InitializeComponent()
            Text = "Calculations"

            lblNumber = New Label
            lblNumber.Location = New Point(17, 23)
            lblNumber.Text = "Number:"
            lblNumber.AutoSize = True

            txtNumber = New TextBox
            txtNumber.Location = New Point(78, 20)
            txtNumber.Size = New Size(83, 20)

            btnCalculate = New Button
            btnCalculate.Location = New Point(78, 45)
            btnCalculate.Text = "Calculate"
            btnCalculate.Size = New Size(83, 23)

            lblResult = New Label
            lblResult.Location = New Point(17, 75)
            lblResult.Text = "Result:"
            lblResult.AutoSize = True

            txtResult = New TextBox
            txtResult.Location = New Point(76, 72)
            txtResult.Size = New Size(83, 20)

            Controls.Add(lblNumber)
            Controls.Add(txtNumber)
            Controls.Add(btnCalculate)
            Controls.Add(lblResult)
            Controls.Add(txtResult)

        End Sub

        Private Sub CalculateClicked(ByVal sender As Object, _
                                     ByVal e As EventArgs) _
                                     Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Number = CDbl(txtNumber.Text)

            Result = Number * 24
            txtResult.Text = CStr(Result)
        End Sub
    End Class

    Function Main() As Integer

        Dim frmStart As Starter = New Starter

        Application.Run(frmStart)

        Return 0
    End Function

End Module

Here is an example of executing it:

Error Handling

The first aspect you should take into consider is to imagine what could cause a problem. If you think there is such a possibility, start by creating a label that could be used to transfer code if a problem occurs. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
        Dim Number As Double
        Dim Result As Double

            Number = CDbl(txtNumber.Text)

        Result = Number * 24
        txtResult.Text = CStr(Result)

ThereWasAProblem:
        MsgBox("There was a problem when executing your instructions")
End Sub

If you create such a label, you should tell the compiler when to jump to that label. Otherwise, as in this case, the label section would always execute. Here is an example of running the above version:

Error Handling

In this case, we want the label section to execute only when we want it to. To prevent the compiler from reaching this section if not directed so, you can add an Exit Sub line above the label section:

Private Sub CalculateClicked(ByVal sender As Object, _
                                     ByVal e As EventArgs) _
                                     Handles btnCalculate.Click
        Dim Number As Double
        Dim Result As Double

            Number = CDbl(txtNumber.Text)

        Result = Number * 24
        txtResult.Text = CStr(Result)

        Exit Sub

ThereWasAProblem:
        MsgBox("There was a problem when executing your instructions")
End Sub

This time if you execute the program with an appropriate value, the label section would not be reached.

In Case Of Error, Jump To Label

The above program will compile fine. When executing it, imagine that the user types an inappropriate value such as 25$.85 instead of 25.85. In this case, the value is not a number, the program would "crash" and let you know that there was a problem:

Error Handling

With some experience, you would know what the problem was, otherwise, you would face a vague explanation. The short story is that the compiler could not continue because, in this case, it could not multiply 25$.85 by another number.

If a problem occurs when a person is using your program, the compiler may display a nasty and insignificant message to the user who would not know what to do with it. Therefore, you can start by creating an appropriate label as introduced above. An error normally occurs in a function. Therefore, to make your code easier to read, you should create a label that shows that it is made for an error instead of being a regular label. The label should also reflect the name of the function. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
        Dim Number As Double
        Dim Result As Double

        Number = CDbl(txtNumber.Text)

        Result = Number * 24
        txtResult.Text = CStr(Result)

        Exit Sub

btnOperation_Click_Error:
        MsgBox("The operation could not be executed", _
               MsgBoxStyle.OkOnly, "Operation Error")
End Sub

When you think there will be a problem in your code, somewhere in the lines under the name of the function but before the line that could cause the problem, type On Error GoTo followed by the name of the label that would deal with the error. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
        On Error GoTo btnOperation_Click_Error

        Dim Number As Double
        Dim Result As Double

        Number = CDbl(txtNumber.Text)

        Result = Number * 24
        txtResult.Text = CStr(Result)

        Exit Sub

btnOperation_Click_Error:
        MsgBox("The operation could not be executed", _
               MsgBoxStyle.OkOnly, "Operation Error")
End Sub

Here is an example of running the program:

Error Handling

When the On Error GoTo statement is used, this indicates to the compiler that if any type of error occurs while the code of this function is executed, transfer the compilation to the label. In this case, as soon as something bad happens, the compiler marks the area where the problem occurred, skips the normal code and jumps to the label indicated by the On Error GoTo line. After the section of that label is executed, the compiler returns where the error occurred. If there is nothing to solve the problem, the compiler continues down but without executing the lines of code involved. In this case, it would encounter the Exit Sub line and get out of the function.

In Case Of Error, Jump To Line #

Although the label is more explicit, it only indicates to the compiler what line to jump to in case of a problem. The alternative is to specify a line number instead of a label.

Resume

If a problem occurs in your code and you provide a label to display a friendly message as done above, the compiler would display the message and exit from the function. If this happens, as mentioned above, when the compiler returns where the problem occurred, you can provide an alternative. For example, in our program, if the user provides an inappropriate value that causes the error, you can provide an alternate value and ask the compiler to continue as if nothing happened. In this case, you want to compiler to "resume" its activity.

To indicate that the program should continue, you can use the Resume keyword. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
        On Error GoTo btnOperation_Click_Error

        Dim Number As Double
        Dim Result As Double

        Number = CDbl(txtNumber.Text)

        Resume

        Result = Number * 24
        txtResult.Text = CStr(Result)

        Exit Sub

btnOperation_Click_Error:
        MsgBox("The operation could not be executed", _
               MsgBoxStyle.OkOnly, "Operation Error")
End Sub

When an error occurs, if you want the program to continue with an alternate value than the one that caused the problem, in the label section, type Resume Next. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
        On Error GoTo btnOperation_Click_Error

        Dim Number As Double
        Dim Result As Double

        Number = CDbl(txtNumber.Text)

        Result = Number * 24
        txtResult.Text = CStr(Result)

        Exit Sub

btnOperation_Click_Error:
        MsgBox("The operation could not be executed", _
               MsgBoxStyle.OkOnly, "Operation Error")
        Resume Next
End Sub

In this case, since any numeric variable is initialized with 0, when the compiler returns to the line of code that caused the problem, it would use 0 as a substitute to the inappropriate value. Based on this, you can provide a new value to use in case of error. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
        On Error GoTo btnOperation_Click_Error

        Dim Number As Double
        Dim Result As Double

        Number = CDbl(txtNumber.Text)

        Result = Number * 24
        txtResult.Text = CStr(Result)

        Exit Sub

btnOperation_Click_Error:
        MsgBox("The operation could not be executed", _
               MsgBoxStyle.OkOnly, "Operation Error")

        Number = 10
        Resume Next
End Sub

Here is one example of running the program:

Error Handling

Here is another example of running the same program:

 
Error Handling Error Handling
 

The Err Object

To support error handling, the Visual Basic library provides a global variable named Err. This allows you to identify the error and its description. Because an error depends on what caused it and why, the values of the Err variable also depend and are not always the same.

Exception Handling Fundamentals

 

Introduction

As opposed to the traditional techniques used to deal with errors, Visual Basic now supports a technique referred to as exception handling. This technique was mostly used by other languages such as C/C++, Object Pascal, C#, etc. This technique is also referred to as structured exception handling (SEH). The On Error GoTo system of dealing with errors is referred to as unstructured exception handling (we will abbreviate is unSEH). There were many concerns with unSEH (mostly lastly used in Microsoft Visual Basic 6):

  • In unSEH, you have to remember to include On Error GoTo sometimes in a random area inside the function. Besides On Error GoTo, you have to remember to create a label section. The name of the label has to be faithfully included in the On Error GoTo line
  • When using the On Error GoTo technique, you have to make sure you get out of the function at the right time, which is done using an Exit Sub line. If you create this Exit Sub line in the wrong area in your function, either the whole code would not be considered or an desired section of the function would still execute, possibly producing an unpredictable result. In the same way, a bizarre way of creating a Resume or a Resume Next line would prevent the compiler from reaching or considering some sections of a function
  • As mentioned previously, the On Error GoTo system provides a global variable named Err. As flexible as good intentioned as it may appear, to effectively use Err, you have to proceed by trial and error because Err identifies errors by a number but its documentation does not possibly provide a list of error numbers. This is because Err not only depends on the application (Visual Basic, VBA, etc) but also it depends on the circumstance in which it is invoked. The only possible solution is to cause an error in your code in order to cause Err to show the numeric error that occurred. Then you have to use that error number and create a custom error message

Because of these uncertainties, you should abandon the On Error GoTo traditional error handling and use SEH in all of your new code. Because SEH and unSEH techniques are inherently different, you cannot use both in the same function.

Practical LearningPractical Learning: Introducing Exception Handling

  1. Start Microsoft Visual Basic if necessary.
    Create a new Windows Application named GeorgetownCleaningServices1
  2. Design the form as follows:
     
    Georgetown Cleaning Services - Cleaning Order Processing
    Control Name Text Additional Properties
    Form     Size: 378, 408
    Label   Customer Name:  
    TextBox txtCustomerName1    
    Label   mm  
    Label   dd  
    Label   yyyy  
    Label   Order Date:  
    TextBox txtMM 1  
    TextBox txtDD 1  
    TextBox txtYYYY 2000  
    Label   Item Types  
    Label   Qty  
    Label   Unit Price  
    Label   Sub-Total  
    Label   Shirts  
    TextBox txtQtyShirts 0  
    TextBox txtUnitPriceShirts 1.15  
    TextBox txtSubTotalShirts 0.00  
    Label   Pants  
    TextBox txtQtyPants 0  
    TextBox txtUnitPricePants 1.95  
    TextBox txtSubTotalPants 0.00  
    Label   Other  
    TextBox txtQtyOther 0  
    TextBox txtUnitPriceOther 3.50  
    TextBox txtSubTotalOther 0.00  
    Button btnProcess Process  
    Label   Customer Name:  
    TextBox txtCustomerName2    
    Label   Order date:  
    TextBox txtOrderDate    
    Label   Tax Rate:  
    TextBox txtTaxRate 5.75  
    Label   %  
    Button btnTax Tax  
    Label   Total Order:  
    TextBox txtTotalOrder 0.00  
    Label   Tax Amount:  
    TextBox txtTaxAmount 0.00  
    Label   Net Price:  
    TextBox txtNetPrice 0.00  
    Label   Amount Tended:  
    TextBox txtAmountTended 0.00  
    Button btnDifference Diff  
    Label   Difference:  
    TextBox txtDifference 0.00  
  3. To arrange the tab sequence, on the main menu, click View -> Tab Order
  4. On the form, click only the following controls whose squares have a white background, in the indicated order:
     
    Georgetown Cleaning Services - Tab Order
  5. Press Esc
  6. Right-click the form and click View Code
  7. Declare a few variables as follows:
     
    Public Class Form1
    
        ' Order Information
        Dim CustomerName As String
        Dim mm As String
        Dim dd As String
        Dim yyyy As String
    
        ' Quantities of items
        Dim NumberOfShirts As Integer
        Dim NumberOfPants As Integer
        Dim NumberOfOther As Integer
    
        ' Price of items
        Dim PriceOneShirt As Double
        Dim PriceAPairOfPants As Double
        Dim PriceOther As Double
    
        ' Each of these sub totals will be used for cleaning items
        Dim SubTotalShirts As Double
        Dim SubTotalPants As Double
        Dim SubTotalOther As Double
    
        ' Values used to process an order
        Dim TaxRate As Double
        Dim TotalOrder As Double
        Dim TaxAmount As Double
        Dim SalesTotal As Double
    
    End Class
  8. In the Class Name combo box, select btnProcess
  9. In the Method Name, select Click and implement its event as follows:
     
    Private Sub btnProcess_Click(ByVal sender As Object, _
                                                   ByVal e As System.EventArgs) _
                                     	Handles btnProcess.Click
            If btnProcess.Text = "Process" Then
                Height = 408
                btnProcess.Text = "Reset"
            Else
                Height = 232
                txtCustomerName1.Text = ""
                txtMM.Text = "1"
                txtDD.Text = "1"
                txtYYYY.Text = "2000"
                txtQtyShirts.Text = "0"
                txtQtyPants.Text = "0"
                txtQtyOther.Text = "0"
                txtSubTotalShirts.Text = "0.00"
                txtSubTotalPants.Text = "0.00"
                txtSubTotalOther.Text = "0.00"
    
                btnProcess.Text = "Process"
            End If
    
            ' Request order information from the user
            CustomerName = txtCustomerName1.Text
            mm = txtMM.Text
            dd = txtDD.Text
            yyyy = txtYYYY.Text
    
            ' Request the quantity of each category of items
            ' Number of Shirts
            NumberOfShirts = CInt(txtQtyShirts.Text)
            ' Number of Pants
            NumberOfPants = CInt(txtQtyPants.Text)
            ' Number of Dresses
            NumberOfOther = CInt(txtQtyOther.Text)
    
            ' Unit Prices of items
            PriceOneShirt = CDbl(txtUnitPriceShirts.Text)
            PriceAPairOfPants = CDbl(txtUnitPricePants.Text)
            PriceOther = CDbl(txtUnitPriceOther.Text)
    
            ' Perform the necessary calculations
            SubTotalShirts = NumberOfShirts * PriceOneShirt
            SubTotalPants = NumberOfPants * PriceAPairOfPants
            SubTotalOther = NumberOfOther * PriceOther
    
            txtSubTotalShirts.Text = CStr(SubTotalShirts)
            txtSubTotalPants.Text = CStr(SubTotalPants)
            txtSubTotalOther.Text = CStr(SubTotalOther)
    
            ' Calculate the "temporary" total of the order
            TotalOrder = SubTotalShirts + SubTotalPants + SubTotalOther
    
            ' Display the receipt
            txtCustomerName2.Text = CustomerName
            txtOrderDate.Text = mm + "/" & dd + "/" & yyyy
            txtTotalOrder.Text = CStr(TotalOrder)
    End Sub
  10. In the Class Name combo box, select btnTax
  11. In the Method Name, select Click and implement its event as follows:
     
    Private Sub btnTax_Click(ByVal sender As Object, _
                                 ByVal e As System.EventArgs) _
                                 Handles btnTax.Click
            ' Get the tax rate
                TaxRate = CDbl(txtTaxRate.Text) / 100
    
            ' Calculate the tax amount using a constant rate
                TaxAmount = TotalOrder * TaxRate
            ' Add the tax amount to the total order
                SalesTotal = TotalOrder + TaxAmount
    
            txtTaxAmount.Text = TaxAmount.ToString()
            txtNetPrice.Text = CStr(SalesTotal)
    End Sub
  12. In the Class Name combo box, select btnDifference
  13. In the Method Name, select Click and implement its event as follows:
     
    Private Sub btnDifference_Click(ByVal sender As Object, _
                                        ByVal e As System.EventArgs) _
                                        Handles btnDifference.Click
            Dim AmountTended As Double = 0.0
            Dim Difference As Double = 0.0
    
            ' Request money for the order
            AmountTended = CDbl(txtAmountTended.Text)
    
            ' Calculate the difference owed to the customer
            ' or that the customer still owes to the store
            Difference = AmountTended - SalesTotal
    
            txtDifference.Text = CStr(Difference)
    End Sub
  14. Return to the form and resize it form to appear as follows:
     
    Georgetown Cleaning Services - Shrunk Form
  15. To execute the application, on the Standard toolbar, click the Start Without Debugging button
     
    Georgetown Cleaning Services Georgetown Cleaning Services
  16. Close the form and return to your programming environment
  17. Execute the application again. This time, type a letter such as d for the quantity of shirts and click Process
     
    Georgetown Cleaning Services - Error
  18. Click Quit to close the form and return to your programming environment

Try to Catch the Error

As mentioned already, errors are likely going to occur in your program. The more you anticipate them and take action, the better your application can be. We have already seen that syntax errors are usually human mistakes such as misspelling, bad formulation of expressions, etc. The compiler will usually help you fix the problem by pointing it out.

SEH is based on two main keywords: Try and Catch. An exception handling section starts with the Try keyword and stops with the End Try statement. Between Try and End Try, there must by at least one Catch section. Therefore, exception handling uses the following formula:

Try
    ' Code to execute in case everything is alright
Catch
    ' If something bad happened, deal with it here
End Try

Exception handling always starts with the Try keyword. Under the Try line, Write the normal code that the compiler must execute. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Try
                Number = CDbl(InputBox("Enter a number:"))
            
            End Try
End Sub

As the compiler is treating code in the Try section, if it encounters a problem, it "gets out" of the Try section and starts looking for a Catch section. Therefore, you MUST always have a Catch section. If you do not, the program will not compile. A Catch section must be written before the End Try line:

Private Sub CalculateClicked(ByVal sender As Object, _
                                              ByVal e As EventArgs) _
                                              Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Try
                Number = CDbl(InputBox("Enter a number:"))
            Catch
                
            End Try
End Sub

When the Catch keyword is simply written as above, it would be asked to treat any error that occurs. For example, if you execute the above code with a number such as 35$.75 instead of 35$.75, nothing would appear to happen. This would indicate that the error was found and vaguely dealt with. One problem in this case is that the compiler would not bother to let the user know why there is no result displayed. Because there can be various types of errors in a program, you also should make your program more intuitive and friendlier so that, when an error occurs, the user would know the type of problem. This is also useful if somebody calls you and says that your program is not functioning right. If there is a way the user can tell you what exact type of error is displaying, maybe you would find the solution faster.

Practical LearningPractical Learning: Catching Exceptions

  1. To introduce exceptions, access the form's code and change the events of the buttons as follows:
     
    Public Class Form1
    
       . . . No Change
    
        Private Sub btnProcess_Click(ByVal sender As Object, _
                                     ByVal e As System.EventArgs) _
                                     Handles btnProcess.Click
            . . . No Change
    
            ' Request the quantity of each category of items
            ' Number of Shirts
            Try
                NumberOfShirts = CInt(txtQtyShirts.Text)
            Catch
    
            End Try
    
            ' Number of Pants
            Try
                NumberOfPants = CInt(txtQtyPants.Text)
            Catch
    
            End Try
    
            ' Number of Dresses
            Try
                NumberOfOther = CInt(txtQtyOther.Text)
            Catch
    
            End Try
    
            ' Unit Prices of items
            Try
                PriceOneShirt = CDbl(txtUnitPriceShirts.Text)
            Catch
    
            End Try
    
            Try
                PriceAPairOfPants = CDbl(txtUnitPricePants.Text)
            Catch
    
            End Try
    
            Try
                PriceOther = CDbl(txtUnitPriceOther.Text)
            Catch
    
            End Try
    
            . . . No Change
        End Sub
    
        Private Sub btnTax_Click(ByVal sender As Object, _
                                 ByVal e As System.EventArgs) _
                                 Handles btnTax.Click
            ' Get the tax rate
            Try
                TaxRate = CDbl(txtTaxRate.Text) / 100
            Catch
    
            End Try
            ' Calculate the tax amount using a constant rate
            TaxAmount = TotalOrder * TaxRate
            ' Add the tax amount to the total order
            SalesTotal = TotalOrder + TaxAmount
    
            txtTaxAmount.Text = TaxAmount.ToString()
            txtNetPrice.Text = SalesTotal.ToString()
        End Sub
    
        Private Sub btnDifference_Click(ByVal sender As Object, _
                                        ByVal e As System.EventArgs) _
                                        Handles btnDifference.Click
            Dim AmountTended As Double = 0.0
            Dim Difference As Double = 0.0
    
            ' Request money for the order
            Try
                AmountTended = CDbl(txtAmountTended.Text)
            Catch
    
            End Try
    
            ' Calculate the difference owed to the customer
            ' or that the customer still owes to the store
            Difference = AmountTended - SalesTotal
    
            txtDifference.Text = CStr(Difference)
        End Sub
    End Class
  2. Execute the application. This time, type invalid values in the quantity text boxes and other text boxes where the user is supposed to enter some values
  3. Click Process
     
    Georgetown Cleaning Services
  4. Return to your programming environment

The Error Message

As mentioned already, if an error occurs when processing the program in the Try section, the compiler transfers the processing to the next Catch section. You can then use the catch section to deal with the error. At a minimum, you can display a message to inform the user. To do this, you can create a message box in the Catch section. Here is an example:

Imports System.Drawing
Imports System.Windows.Forms

Module Exercise

    Public Class Starter
        Inherits Form

        Private lblNumber As Label
        Private txtNumber As TextBox
        Friend WithEvents btnCalculate As Button
        Private lblResult As Label
        Private txtResult As TextBox

        Dim components As System.ComponentModel.Container

        Public Sub New()
            InitializeComponent()
        End Sub

        Public Sub InitializeComponent()
            Text = "Exception Behavior"

            lblNumber = New Label
            lblNumber.Location = New Point(17, 23)
            lblNumber.Text = "Number:"
            lblNumber.AutoSize = True

            txtNumber = New TextBox
            txtNumber.Location = New Point(78, 20)
            txtNumber.Size = New Size(83, 20)

            btnCalculate = New Button
            btnCalculate.Location = New Point(78, 45)
            btnCalculate.Text = "Calculate"
            btnCalculate.Size = New Size(83, 23)

            lblResult = New Label
            lblResult.Location = New Point(17, 75)
            lblResult.Text = "Result:"
            lblResult.AutoSize = True

            txtResult = New TextBox
            txtResult.Location = New Point(76, 72)
            txtResult.Size = New Size(83, 20)

            Controls.Add(lblNumber)
            Controls.Add(txtNumber)
            Controls.Add(btnCalculate)
            Controls.Add(lblResult)
            Controls.Add(txtResult)

        End Sub

        Private Sub CalculateClicked(ByVal sender As Object, _
                                     	      ByVal e As EventArgs) _
                                     	      Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Try
                Number = CDbl(txtNumber.Text)
                Result = Number * 12.48
                txtResult.Text = CStr(Result)
            Catch
                MsgBox("Something bad happened")
            End Try
        End Sub
    End Class

    Function Main() As Integer

        Dim frmStart As Starter = New Starter

        Application.Run(frmStart)

        Return 0
    End Function

End Module

Custom Message

Of course, your message may not be particularly clear but this time, the program will not crash.

Practical LearningPractical Learning: Displaying Custom Messages

  1. To display custom messages to the user, change the code as follows:
     
    Public Class Form1
    
        . . . No Change
    
        Private Sub btnProcess_Click(ByVal sender As Object, _
                                     ByVal e As System.EventArgs) _
                                     Handles btnProcess.Click
            . . . No Change
    
            ' Request the quantity of each category of items
            ' Number of Shirts
            Try
                NumberOfShirts = CInt(txtQtyShirts.Text)
            Catch
                MsgBox("The value you typed for the number of " & _
                       "shirts is not a valid number." & _
                       vbCrLf & "Please enter a natural number such " & _
                       "as 2 or 24 or even 248")
            End Try
    
            ' Number of Pants
            Try
                NumberOfPants = CInt(txtQtyPants.Text)
            Catch
                MsgBox("The value you typed for the number of " & _
                       "pair or pants is not a valid number." & _
                       vbCrLf & "Please enter a natural number such " & _
                       "as 2 or 24 or even 248")
            End Try
    
            ' Number of other items
            Try
                NumberOfOther = CInt(txtQtyOther.Text)
            Catch
                MsgBox("The value you typed for the number of " & _
                       "other items is not a valid number." & _
                       vbCrLf & "Please enter a natural number such " & _
                       "as 2 or 24 or even 248")
            End Try
    
            ' Unit Prices of items
            Try
                PriceOneShirt = CDbl(txtUnitPriceShirts.Text)
            Catch
                MsgBox("The value you entered for the unit price " & _
                       "of a shirt is not a recognizable currency " & _
                       "amount." & vbCrLf & _
                       "Only natural or decimal numbers " & _
                       "are allowed. Please consult the management " & _
                       "to know the valid prices.")
            End Try
    
            Try
                PriceAPairOfPants = CDbl(txtUnitPricePants.Text)
            Catch
                MsgBox("The value you entered for the unit price of " & _
                       "a pair of pants is not a recognizable " & _
                       "currency amount." & vbCrLf & _
                       "Only natural or decimal " & _
                       "numbers are allowed. You can consult the " & _
                       "management to find out about " & _
                       "the allowable prices.")
            End Try
    
            Try
                PriceOther = CDbl(txtUnitPriceOther.Text)
            Catch
                MsgBox("The value you entered for the unit " & _
                       "price of other items is not a valid amount." & _
                       vbCrLf & "You must enter only a natural or a " & _
                       "decimal number. For more information, " & _
                       "please consult the management to get " & _
                       "the right prices.")
            End Try
    
            . . . No Change
        End Sub
    
        Private Sub btnTax_Click(ByVal sender As Object, _
                                 ByVal e As System.EventArgs) _
                                 Handles btnTax.Click
            ' Get the tax rate
            Try
                TaxRate = CDbl(txtTaxRate.Text) / 100
            Catch
                MsgBox("The value you entered is not " & _
                       "recognized as a valid tax rate." & _
                       vbCrLf & "A valid tax rate is a value " & _
                       "between 0 and 100.00" & _
                       vbCrLf & "Please try again.")
            End Try
            ' Calculate the tax amount using a constant rate
            TaxAmount = TotalOrder * TaxRate
            ' Add the tax amount to the total order
            SalesTotal = TotalOrder + TaxAmount
    
            txtTaxAmount.Text = TaxAmount.ToString()
            txtNetPrice.Text = SalesTotal.ToString()
        End Sub
    
        Private Sub btnDifference_Click(ByVal sender As Object, _
                                        ByVal e As System.EventArgs) _
                                        Handles btnDifference.Click
            Dim AmountTended As Double = 0.0
            Dim Difference As Double = 0.0
    
            ' Request money for the order
            Try
                AmountTended = CDbl(txtAmountTended.Text)
            Catch
                MsgBox("The value you entered for the amount " & _
                       "tended is not valid. Only natural or " & _
                       "decimal numbers are allowed." & _
                       "Please try again.")
            End Try
    
            ' Calculate the difference owed to the customer
            ' or that the customer still owes to the store
            Difference = AmountTended - SalesTotal
    
            txtDifference.Text = CStr(Difference)
        End Sub
    End Class
  2. Test the application with valid and invalid values. Here is an example:
     

    Georgetown Cleaning Services

  3. Return to Notepad

Exceptions in the .NET Framework

 

The Exception Class

Most libraries such as Borland's VCL and Microsoft's MFC ship with their own classes to handle exceptions. Even the Win32 library provides its type of mechanism to face errors. To support exception handling, the .NET Framework provides a special class called Exception. Once the compiler encounters an error, the Exception class allows you to identify the type of error and take an appropriate action.

Normally, Exception mostly serves as the general class of exceptions. It is used like a Catch that is not followed by any parameter. Anticipating various types of problems that can occur in a program, Microsoft derived various classes from Exception to make this issue friendlier. As a result, almost any type of exception you may encounter already has a class created to deal with it. Therefore, when your program faces an exception, you can easily identify the type of error.

There are so many exception classes that we cannot study or review them all. The solution we will use is to introduce or review a class when we meet its type of error.

In exception handling, errors are dealt with in the Catch clause. To use it, on the right side of Catch, type a parameter name, followed by the As operator, and followed by the the type of exception you want to deal with. By default, an exception is first of type Exception. Based on this, a typical formula to implement exception handling is:

Private Sub CalculateClicked(ByVal sender As Object, _
                                     	      ByVal e As EventArgs) _
                                     	      Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Try

                ' Process the normal flow of the program here

            Catch ex As Exception

                ' Deal with the exception here

            End Try

End Sub

As reviewed already, when an exception occurs in the Try section, code compilation is transferred to the Catch section. If you declare the exception as an Exception type, this class will identify the error.

The Exception's Message

One of the properties of the Exception class is called Message. This property contains a string that describes the type of error that occurred. You can then use this Exception.Message property to display an error message if you want. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                     ByVal e As EventArgs) _
                                     Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Try
                Number = CDbl(txtNumber.Text)
                Result = Number * 12.48
                txtResult.Text = CStr(Result)
            Catch ex As Exception
                MsgBox(ex.Message)
            End Try
End Sub

An exception using the Exception.Message message

Custom Error Messages

As you can see, one of the strengths of the Message property is that it gives you a good indication of the type of problem that occurred. Sometimes, the message provided by the Exception class may not appear explicit enough. In fact, you may not want to show it to the user since, as in this case, the user may not understand what the message means and why it is being used. As an alternative, you can create your own message and display it to the user. As seen previously, to display your own message, in the Catch section, use the MsgBox() function to create and display a message. Here is an example:

Private Sub CalculateClicked(ByVal sender As Object, _
                                     ByVal e As EventArgs) _
                                     Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Try
                Number = CDbl(txtNumber.Text)
                Result = Number * 12.48
                txtResult.Text = CStr(Result)
            Catch ex As Exception
                MsgBox("The operation could not be carried because " & _
                             "the number you typed is not valid")
            End Try
End Sub

An exception with a custom message

You can also combine the Exception.Message message and your own message:

Private Sub CalculateClicked(ByVal sender As Object, _
                                     ByVal e As EventArgs) _
                                     Handles btnCalculate.Click
            Dim Number As Double
            Dim Result As Double

            Try
                Number = CDbl(txtNumber.Text)
                Result = Number * 12.48
                txtResult.Text = CStr(Result)
            Catch ex As Exception
                MsgBox(ex.Message & _
                       vbCrLf & "The operation could not be carried because " & _
                       "the number you typed is not valid")
            End Try
End Sub

Exception Handling

 

Exercises

 

Georgetown Cleaning Services

  1. Open the GeorgetownCleaningServices1 application from this lesson
  2. Add the tooltips to all controls on the form
  3. Create a help file that will assist the user with the application

Clarksville Ice Cream

  1. Create a Windows Application named ClarskvilleIceCream1a
  2. Design the form as follows:
     
  3. Add tool tips and help to the application
 
 

Previous Copyright 2008-2009, yevol.com Next